mirror of https://gitee.com/bigwinds/arangodb
Merge branch 'devel' of github.com:arangodb/ArangoDB into devel
This commit is contained in:
Wilfried Goesgens
commit
c1643864c3
|
|
@ -1,229 +0,0 @@
|
|||
#.rst:
|
||||
# FindBISON
|
||||
# ---------
|
||||
#
|
||||
# Find ``bison`` executable and provide a macro to generate custom build rules.
|
||||
#
|
||||
# The module defines the following variables:
|
||||
#
|
||||
# ``BISON_EXECUTABLE``
|
||||
# path to the ``bison`` program
|
||||
#
|
||||
# ``BISON_VERSION``
|
||||
# version of ``bison``
|
||||
#
|
||||
# ``BISON_FOUND``
|
||||
# true if the program was found
|
||||
#
|
||||
# The minimum required version of ``bison`` can be specified using the
|
||||
# standard CMake syntax, e.g. ``find_package(BISON 2.1.3)``.
|
||||
#
|
||||
# If ``bison`` is found, the module defines the macro::
|
||||
#
|
||||
# BISON_TARGET(<Name> <YaccInput> <CodeOutput>
|
||||
# [COMPILE_FLAGS <flags>]
|
||||
# [DEFINES_FILE <file>]
|
||||
# [VERBOSE <file>]
|
||||
# )
|
||||
#
|
||||
# which will create a custom rule to generate a parser. ``<YaccInput>`` is
|
||||
# the path to a yacc file. ``<CodeOutput>`` is the name of the source file
|
||||
# generated by bison. A header file is also be generated, and contains
|
||||
# the token list.
|
||||
#
|
||||
# The options are:
|
||||
#
|
||||
# ``COMPILE_FLAGS <flags>``
|
||||
# Specify flags to be added to the ``bison`` command line.
|
||||
#
|
||||
# ``DEFINES_FILE <file>``
|
||||
# Specify a non-default header ``<file>`` to be generated by ``bison``.
|
||||
#
|
||||
# ``VERBOSE <file>``
|
||||
# Tell ``bison`` to write verbose descriptions of the grammar and
|
||||
# parser to the given ``<file>``.
|
||||
#
|
||||
# The macro defines the following variables:
|
||||
#
|
||||
# ``BISON_<Name>_DEFINED``
|
||||
# true is the macro ran successfully
|
||||
#
|
||||
# ``BISON_<Name>_INPUT``
|
||||
# The input source file, an alias for <YaccInput>
|
||||
#
|
||||
# ``BISON_<Name>_OUTPUT_SOURCE``
|
||||
# The source file generated by bison
|
||||
#
|
||||
# ``BISON_<Name>_OUTPUT_HEADER``
|
||||
# The header file generated by bison
|
||||
#
|
||||
# ``BISON_<Name>_OUTPUTS``
|
||||
# The sources files generated by bison
|
||||
#
|
||||
# ``BISON_<Name>_COMPILE_FLAGS``
|
||||
# Options used in the ``bison`` command line
|
||||
#
|
||||
# Example usage:
|
||||
#
|
||||
# .. code-block:: cmake
|
||||
#
|
||||
# find_package(BISON)
|
||||
# BISON_TARGET(MyParser parser.y ${CMAKE_CURRENT_BINARY_DIR}/parser.cpp
|
||||
# DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/parser.h)
|
||||
# add_executable(Foo main.cpp ${BISON_MyParser_OUTPUTS})
|
||||
|
||||
#=============================================================================
|
||||
# Copyright 2009 Kitware, Inc.
|
||||
# Copyright 2006 Tristan Carel
|
||||
#
|
||||
# Distributed under the OSI-approved BSD License (the "License");
|
||||
# see accompanying file Copyright.txt for details.
|
||||
#
|
||||
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
||||
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
# See the License for more information.
|
||||
#=============================================================================
|
||||
# (To distribute this file outside of CMake, substitute the full
|
||||
# License text for the above reference.)
|
||||
|
||||
find_program(BISON_EXECUTABLE NAMES bison win_bison DOC "path to the bison executable")
|
||||
mark_as_advanced(BISON_EXECUTABLE)
|
||||
|
||||
include(CMakeParseArguments)
|
||||
|
||||
if(BISON_EXECUTABLE)
|
||||
# the bison commands should be executed with the C locale, otherwise
|
||||
# the message (which are parsed) may be translated
|
||||
set(_Bison_SAVED_LC_ALL "$ENV{LC_ALL}")
|
||||
set(ENV{LC_ALL} C)
|
||||
|
||||
execute_process(COMMAND ${BISON_EXECUTABLE} --version
|
||||
OUTPUT_VARIABLE BISON_version_output
|
||||
ERROR_VARIABLE BISON_version_error
|
||||
RESULT_VARIABLE BISON_version_result
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
|
||||
set(ENV{LC_ALL} ${_Bison_SAVED_LC_ALL})
|
||||
|
||||
if(NOT ${BISON_version_result} EQUAL 0)
|
||||
message(SEND_ERROR "Command \"${BISON_EXECUTABLE} --version\" failed with output:\n${BISON_version_error}")
|
||||
else()
|
||||
# Bison++
|
||||
if("${BISON_version_output}" MATCHES "^bison\\+\\+ Version ([^,]+)")
|
||||
set(BISON_VERSION "${CMAKE_MATCH_1}")
|
||||
# GNU Bison
|
||||
elseif("${BISON_version_output}" MATCHES "^bison \\(GNU Bison\\) ([^\n]+)\n")
|
||||
set(BISON_VERSION "${CMAKE_MATCH_1}")
|
||||
elseif("${BISON_version_output}" MATCHES "^GNU Bison (version )?([^\n]+)")
|
||||
set(BISON_VERSION "${CMAKE_MATCH_2}")
|
||||
endif()
|
||||
endif()
|
||||
|
||||
# internal macro
|
||||
macro(BISON_TARGET_option_verbose Name BisonOutput filename)
|
||||
list(APPEND BISON_TARGET_cmdopt "--verbose")
|
||||
get_filename_component(BISON_TARGET_output_path "${BisonOutput}" PATH)
|
||||
get_filename_component(BISON_TARGET_output_name "${BisonOutput}" NAME_WE)
|
||||
add_custom_command(OUTPUT ${filename}
|
||||
COMMAND ${CMAKE_COMMAND}
|
||||
ARGS -E copy
|
||||
"${BISON_TARGET_output_path}/${BISON_TARGET_output_name}.output"
|
||||
"${filename}"
|
||||
DEPENDS
|
||||
"${BISON_TARGET_output_path}/${BISON_TARGET_output_name}.output"
|
||||
COMMENT "[BISON][${Name}] Copying bison verbose table to ${filename}"
|
||||
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
|
||||
set(BISON_${Name}_VERBOSE_FILE ${filename})
|
||||
list(APPEND BISON_TARGET_extraoutputs
|
||||
"${BISON_TARGET_output_path}/${BISON_TARGET_output_name}.output")
|
||||
endmacro()
|
||||
|
||||
# internal macro
|
||||
macro(BISON_TARGET_option_extraopts Options)
|
||||
set(BISON_TARGET_extraopts "${Options}")
|
||||
separate_arguments(BISON_TARGET_extraopts)
|
||||
list(APPEND BISON_TARGET_cmdopt ${BISON_TARGET_extraopts})
|
||||
endmacro()
|
||||
|
||||
# internal macro
|
||||
macro(BISON_TARGET_option_defines Header)
|
||||
set(BISON_TARGET_output_header "${Header}")
|
||||
list(APPEND BISON_TARGET_cmdopt --defines=${BISON_TARGET_output_header})
|
||||
endmacro()
|
||||
|
||||
#============================================================
|
||||
# BISON_TARGET (public macro)
|
||||
#============================================================
|
||||
#
|
||||
macro(BISON_TARGET Name BisonInput BisonOutput)
|
||||
set(BISON_TARGET_output_header "")
|
||||
set(BISON_TARGET_cmdopt "")
|
||||
set(BISON_TARGET_outputs "${BisonOutput}")
|
||||
|
||||
# Parsing parameters
|
||||
set(BISON_TARGET_PARAM_OPTIONS)
|
||||
set(BISON_TARGET_PARAM_ONE_VALUE_KEYWORDS
|
||||
VERBOSE
|
||||
COMPILE_FLAGS
|
||||
DEFINES_FILE
|
||||
)
|
||||
set(BISON_TARGET_PARAM_MULTI_VALUE_KEYWORDS)
|
||||
cmake_parse_arguments(
|
||||
BISON_TARGET_ARG
|
||||
"${BISON_TARGET_PARAM_OPTIONS}"
|
||||
"${BISON_TARGET_PARAM_ONE_VALUE_KEYWORDS}"
|
||||
"${BISON_TARGET_PARAM_MULTI_VALUE_KEYWORDS}"
|
||||
${ARGN}
|
||||
)
|
||||
|
||||
if(NOT "${BISON_TARGET_ARG_UNPARSED_ARGUMENTS}" STREQUAL "")
|
||||
message(SEND_ERROR "Usage")
|
||||
else()
|
||||
if(NOT "${BISON_TARGET_ARG_VERBOSE}" STREQUAL "")
|
||||
BISON_TARGET_option_verbose(${Name} ${BisonOutput} "${BISON_TARGET_ARG_VERBOSE}")
|
||||
endif()
|
||||
if(NOT "${BISON_TARGET_ARG_COMPILE_FLAGS}" STREQUAL "")
|
||||
BISON_TARGET_option_extraopts("${BISON_TARGET_ARG_COMPILE_FLAGS}")
|
||||
endif()
|
||||
if(NOT "${BISON_TARGET_ARG_DEFINES_FILE}" STREQUAL "")
|
||||
BISON_TARGET_option_defines("${BISON_TARGET_ARG_DEFINES_FILE}")
|
||||
endif()
|
||||
|
||||
if("${BISON_TARGET_output_header}" STREQUAL "")
|
||||
# Header's name generated by bison (see option -d)
|
||||
list(APPEND BISON_TARGET_cmdopt "-d")
|
||||
string(REGEX REPLACE "^(.*)(\\.[^.]*)$" "\\2" _fileext "${BisonOutput}")
|
||||
string(REPLACE "c" "h" _fileext ${_fileext})
|
||||
string(REGEX REPLACE "^(.*)(\\.[^.]*)$" "\\1${_fileext}"
|
||||
BISON_TARGET_output_header "${BisonOutput}")
|
||||
endif()
|
||||
list(APPEND BISON_TARGET_outputs "${BISON_TARGET_output_header}")
|
||||
|
||||
add_custom_command(OUTPUT ${BISON_TARGET_outputs}
|
||||
${BISON_TARGET_extraoutputs}
|
||||
COMMAND ${BISON_EXECUTABLE}
|
||||
ARGS ${BISON_TARGET_cmdopt} -o ${BisonOutput} ${BisonInput}
|
||||
DEPENDS ${BisonInput}
|
||||
COMMENT "[BISON][${Name}] Building parser with bison ${BISON_VERSION}"
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
|
||||
|
||||
# define target variables
|
||||
set(BISON_${Name}_DEFINED TRUE)
|
||||
set(BISON_${Name}_INPUT ${BisonInput})
|
||||
set(BISON_${Name}_OUTPUTS ${BISON_TARGET_outputs})
|
||||
set(BISON_${Name}_COMPILE_FLAGS ${BISON_TARGET_cmdopt})
|
||||
set(BISON_${Name}_OUTPUT_SOURCE "${BisonOutput}")
|
||||
set(BISON_${Name}_OUTPUT_HEADER "${BISON_TARGET_output_header}")
|
||||
|
||||
endif()
|
||||
endmacro()
|
||||
#
|
||||
#============================================================
|
||||
|
||||
endif()
|
||||
|
||||
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
||||
FIND_PACKAGE_HANDLE_STANDARD_ARGS(BISON REQUIRED_VARS BISON_EXECUTABLE
|
||||
VERSION_VAR BISON_VERSION)
|
||||
|
||||
# FindBISON.cmake ends here
|
||||
|
|
@ -1,202 +0,0 @@
|
|||
#.rst:
|
||||
# FindFLEX
|
||||
# --------
|
||||
#
|
||||
# Find flex executable and provides a macro to generate custom build rules
|
||||
#
|
||||
#
|
||||
#
|
||||
# The module defines the following variables:
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# FLEX_FOUND - true is flex executable is found
|
||||
# FLEX_EXECUTABLE - the path to the flex executable
|
||||
# FLEX_VERSION - the version of flex
|
||||
# FLEX_LIBRARIES - The flex libraries
|
||||
# FLEX_INCLUDE_DIRS - The path to the flex headers
|
||||
#
|
||||
#
|
||||
#
|
||||
# The minimum required version of flex can be specified using the
|
||||
# standard syntax, e.g. find_package(FLEX 2.5.13)
|
||||
#
|
||||
#
|
||||
#
|
||||
# If flex is found on the system, the module provides the macro:
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# FLEX_TARGET(Name FlexInput FlexOutput [COMPILE_FLAGS <string>])
|
||||
#
|
||||
# which creates a custom command to generate the <FlexOutput> file from
|
||||
# the <FlexInput> file. If COMPILE_FLAGS option is specified, the next
|
||||
# parameter is added to the flex command line. Name is an alias used to
|
||||
# get details of this custom command. Indeed the macro defines the
|
||||
# following variables:
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# FLEX_${Name}_DEFINED - true is the macro ran successfully
|
||||
# FLEX_${Name}_OUTPUTS - the source file generated by the custom rule, an
|
||||
# alias for FlexOutput
|
||||
# FLEX_${Name}_INPUT - the flex source file, an alias for ${FlexInput}
|
||||
#
|
||||
#
|
||||
#
|
||||
# Flex scanners oftenly use tokens defined by Bison: the code generated
|
||||
# by Flex depends of the header generated by Bison. This module also
|
||||
# defines a macro:
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# ADD_FLEX_BISON_DEPENDENCY(FlexTarget BisonTarget)
|
||||
#
|
||||
# which adds the required dependency between a scanner and a parser
|
||||
# where <FlexTarget> and <BisonTarget> are the first parameters of
|
||||
# respectively FLEX_TARGET and BISON_TARGET macros.
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# ====================================================================
|
||||
# Example:
|
||||
#
|
||||
#
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# find_package(BISON)
|
||||
# find_package(FLEX)
|
||||
#
|
||||
#
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# BISON_TARGET(MyParser parser.y ${CMAKE_CURRENT_BINARY_DIR}/parser.cpp)
|
||||
# FLEX_TARGET(MyScanner lexer.l ${CMAKE_CURRENT_BINARY_DIR}/lexer.cpp)
|
||||
# ADD_FLEX_BISON_DEPENDENCY(MyScanner MyParser)
|
||||
#
|
||||
#
|
||||
#
|
||||
# ::
|
||||
#
|
||||
# include_directories(${CMAKE_CURRENT_BINARY_DIR})
|
||||
# add_executable(Foo
|
||||
# Foo.cc
|
||||
# ${BISON_MyParser_OUTPUTS}
|
||||
# ${FLEX_MyScanner_OUTPUTS}
|
||||
# )
|
||||
# ====================================================================
|
||||
|
||||
#=============================================================================
|
||||
# Copyright 2009 Kitware, Inc.
|
||||
# Copyright 2006 Tristan Carel
|
||||
#
|
||||
# Distributed under the OSI-approved BSD License (the "License");
|
||||
# see accompanying file Copyright.txt for details.
|
||||
#
|
||||
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
||||
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
# See the License for more information.
|
||||
#=============================================================================
|
||||
# (To distribute this file outside of CMake, substitute the full
|
||||
# License text for the above reference.)
|
||||
|
||||
find_program(FLEX_EXECUTABLE NAMES flex win_flex DOC "path to the flex executable")
|
||||
mark_as_advanced(FLEX_EXECUTABLE)
|
||||
|
||||
find_library(FL_LIBRARY NAMES fl
|
||||
DOC "Path to the fl library")
|
||||
|
||||
find_path(FLEX_INCLUDE_DIR FlexLexer.h
|
||||
DOC "Path to the flex headers")
|
||||
|
||||
mark_as_advanced(FL_LIBRARY FLEX_INCLUDE_DIR)
|
||||
|
||||
set(FLEX_INCLUDE_DIRS ${FLEX_INCLUDE_DIR})
|
||||
set(FLEX_LIBRARIES ${FL_LIBRARY})
|
||||
|
||||
if(FLEX_EXECUTABLE)
|
||||
|
||||
execute_process(COMMAND ${FLEX_EXECUTABLE} --version
|
||||
OUTPUT_VARIABLE FLEX_version_output
|
||||
ERROR_VARIABLE FLEX_version_error
|
||||
RESULT_VARIABLE FLEX_version_result
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
if(NOT ${FLEX_version_result} EQUAL 0)
|
||||
if(FLEX_FIND_REQUIRED)
|
||||
message(SEND_ERROR "Command \"${FLEX_EXECUTABLE} --version\" failed with output:\n${FLEX_version_output}\n${FLEX_version_error}")
|
||||
else()
|
||||
message("Command \"${FLEX_EXECUTABLE} --version\" failed with output:\n${FLEX_version_output}\n${FLEX_version_error}\nFLEX_VERSION will not be available")
|
||||
endif()
|
||||
else()
|
||||
# older versions of flex printed "/full/path/to/executable version X.Y"
|
||||
# newer versions use "basename(executable) X.Y"
|
||||
get_filename_component(FLEX_EXE_NAME_WE "${FLEX_EXECUTABLE}" NAME_WE)
|
||||
get_filename_component(FLEX_EXE_EXT "${FLEX_EXECUTABLE}" EXT)
|
||||
string(REGEX REPLACE "^.*${FLEX_EXE_NAME_WE}(${FLEX_EXE_EXT})?\"? (version )?([0-9]+[^ ]*)( .*)?$" "\\3"
|
||||
FLEX_VERSION "${FLEX_version_output}")
|
||||
unset(FLEX_EXE_EXT)
|
||||
unset(FLEX_EXE_NAME_WE)
|
||||
endif()
|
||||
|
||||
#============================================================
|
||||
# FLEX_TARGET (public macro)
|
||||
#============================================================
|
||||
#
|
||||
macro(FLEX_TARGET Name Input Output)
|
||||
set(FLEX_TARGET_usage "FLEX_TARGET(<Name> <Input> <Output> [COMPILE_FLAGS <string>]")
|
||||
if(${ARGC} GREATER 3)
|
||||
if(${ARGC} EQUAL 5)
|
||||
if("${ARGV3}" STREQUAL "COMPILE_FLAGS")
|
||||
set(FLEX_EXECUTABLE_opts "${ARGV4}")
|
||||
separate_arguments(FLEX_EXECUTABLE_opts)
|
||||
else()
|
||||
message(SEND_ERROR ${FLEX_TARGET_usage})
|
||||
endif()
|
||||
else()
|
||||
message(SEND_ERROR ${FLEX_TARGET_usage})
|
||||
endif()
|
||||
endif()
|
||||
|
||||
add_custom_command(OUTPUT ${Output}
|
||||
COMMAND ${FLEX_EXECUTABLE}
|
||||
ARGS ${FLEX_EXECUTABLE_opts} -o${Output} ${Input}
|
||||
DEPENDS ${Input}
|
||||
COMMENT "[FLEX][${Name}] Building scanner with flex ${FLEX_VERSION}"
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
|
||||
|
||||
set(FLEX_${Name}_DEFINED TRUE)
|
||||
set(FLEX_${Name}_OUTPUTS ${Output})
|
||||
set(FLEX_${Name}_INPUT ${Input})
|
||||
set(FLEX_${Name}_COMPILE_FLAGS ${FLEX_EXECUTABLE_opts})
|
||||
endmacro()
|
||||
#============================================================
|
||||
|
||||
|
||||
#============================================================
|
||||
# ADD_FLEX_BISON_DEPENDENCY (public macro)
|
||||
#============================================================
|
||||
#
|
||||
macro(ADD_FLEX_BISON_DEPENDENCY FlexTarget BisonTarget)
|
||||
|
||||
if(NOT FLEX_${FlexTarget}_OUTPUTS)
|
||||
message(SEND_ERROR "Flex target `${FlexTarget}' does not exists.")
|
||||
endif()
|
||||
|
||||
if(NOT BISON_${BisonTarget}_OUTPUT_HEADER)
|
||||
message(SEND_ERROR "Bison target `${BisonTarget}' does not exists.")
|
||||
endif()
|
||||
|
||||
set_source_files_properties(${FLEX_${FlexTarget}_OUTPUTS}
|
||||
PROPERTIES OBJECT_DEPENDS ${BISON_${BisonTarget}_OUTPUT_HEADER})
|
||||
endmacro()
|
||||
#============================================================
|
||||
|
||||
endif()
|
||||
|
||||
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
||||
FIND_PACKAGE_HANDLE_STANDARD_ARGS(FLEX REQUIRED_VARS FLEX_EXECUTABLE
|
||||
VERSION_VAR FLEX_VERSION)
|
||||
|
||||
# FindFLEX.cmake ends here
|
||||
Loading…
Reference in New Issue